Erick Kurniawan

Buku ASP.NET 3.5

Erick Kurniawan — Tue, 23 Feb 2010 06:18:43 GMT

Judul :	ASP.NET 3.5 untuk Aplikasi Web Interaktif
Penulis :	Erick Kurniawan
Tahun :	2010
Penerbit :	Penerbit Andi
Hal :	260
Sinopsis :	Buku ini berisi teknik dan cara praktis yang disertai dengan contoh yang akan menuntun anda untuk membangun aplikasi web dinamis menggunakan framework ASP.NET 3.5 dan bahasa C# secara bertahap. Buku ini memiliki penjelasan yang terstruktur mengenai fitur-fitur ASP.NET seperti Server Control, Theme, Membership, ADO.NET, Data Binding, Master Page, Validation, dan Data Bound control. Buku juga ini juga membahas fitur-fitur baru yang ada pada ASP.NET 3.5 dan C# 3.0 seperti LINQ (Language Integrated Query) dan LinqDataSource yang akan memudahkan anda bekerja dengan data seperti melakukan query ke object collection, database, atau xml. ListView dan DataPager yang merupakan control baru pada ASP.NET 3.5 yang sangat fleksible untuk menampilkan dan melakukan paging pada data. ASP.NET AJAX dan AJAX Control Toolkit untuk menambahkan interaktifitas dan performa aplikasi web anda.
	beli disini

Event : Skill Accelerator @MIC UGM

Erick Kurniawan — Mon, 08 Feb 2010 06:16:15 GMT

Pada Tanggal 25 January 2009 dilangsungkan acara Skill Accelerator yang diadakan oleh MIC UGM dengan tema “AJAX Technology”, saya mendapat bagian untuk memberikan workshop pada sesi “ASP.NET with JQuery”. Untuk materi yang lain yaitu ASP.NET AJAX dibawakan oleh Pak Ridi dan Pak Komang dari MIC UGM. Peserta kebanyakan adalah dosen dan guru pengajar.

Acara Microsoft Faculty Summit di UGM

Erick Kurniawan — Sun, 11 Oct 2009 07:55:00 GMT

Pada hari senin tanggal 5 Oktober 2009, MIC UGM yang didukung oleh Microsoft Indonesia telah melangsungkan acara Facullty Summit. Acara ini diikuti oleh dosen dan guru pengajar bidang TI yang ada di daerah jogjakarta dan sekitarnya. Acara ini sendiri bertujuan untuk mengupdate kemampuan para dosen dan guru di bidang MS Technology. Pada faculty summit kali ini temanya adalah ‘Blogengine Just Code It’, dengan susunan materi :

BlogEngine 101 oleh Pak Ridi Ferdiana
BlogEngine Theme oleh Mas Ferro Ferizka
Blogengine Extension/Widget oleh Erick Kurniawan

Diharapkan acara ini dapat terus berkelanjutan agar kita dapat ikut berkontribusi untuk dunia pendidikan di Indonesia.

Adapun foto-foto pada saat acara tersebut berlangsung adalah sebagai berikut:

Pak Ridi Ferdiana in Action :)

Mas Ferro dengan materi BlogEngine Theme

Saya membawakan topik Blogengine Extension/Widget

Seminar di Universitas Negri Yogyakarta

Erick Kurniawan — Sun, 11 Oct 2009 06:42:44 GMT

Pada hari Sabtu, tanggal 10 Oktober 2009 MUGI Jogja ikut berpartisipasi dalam seminar Technology Update di kampus Uneversitas Negri Yogyakarta. Seminar tersebut terdiri dari 3 sesi yang terdiri dari:

AMD Gigabyte Technology : Benny Lodewjk
Green Computing : Priyanto (Dosen UNY)
Windows 7 For Developer : Erick Kurniawan (MUGI Jogja)

Acara seminar ini dilangsungkan di Gedung KPLT Fakultas Teknik UNY dan dihadiri oleh 218 peserta, adapun foto-foto pada saat seminar ini berlangsung sebagai berikut:

Penyerahan kenang2an kaos (dari MS Indo) kepada peserta :

Foto-foto dengan panitai seminar, pembicara dan Pak Adjie

Terima Kasih kepada rekan2 MUGI Jogja (feronic, ve2, bas, dll), Panitia UNY (ryan, farid, dll) atas dukungannya

Terima Kasih juga untuk mas Ronald dan Naren (MS Indo) atas dukungan goodies-nya :)

Acara Seminar di Universitas Negeri Yogyakarta

Erick Kurniawan — Tue, 29 Sep 2009 05:59:00 GMT

Pada tanggal 10 Oktober 2009 akan diadakan Seminar Technology Update di Universitas Negri Yogyakarta (UNY) http://www.uny.ac.id/.

Pada seminar tersebut saya mewakili MUGI (Microsoft User Group Indonesia) Jogja akan menyampaikan materi Pengenalan Kominitas MUGI dan Windows 7 for Developer menggunakan Windows7 CodePack API.

Mohon dukungan teman-teman semoga acara berjalan lancar dan komunitas MUGI semakin besar dan terkenal di kota Gudeg :)

I'm A VB!

Erick Kurniawan — Sat, 11 Jul 2009 15:48:17 GMT

Who’s the “typical VB.NET developer”? Is there one? There are millions of VB.NET developers in the world, and they each have their own unique story. We decided to talk to some of them to find out what kinds of applications they’re building, what technologies they’re using, and what their favorite features are.

Lihat interview : View the interviews

Apakah anda juga VB developer? Tell your story here

Fitur VB10 (Collection Initializer)

Erick Kurniawan — Sat, 11 Jul 2009 15:46:44 GMT

Blog sebelumnya seputar Fitur-fitur VB10 dapat anda baca di:

Collection Initializer digunakan untuk menginisialisasi object collection dalam sebuah baris kode saja, sehingga mempermudah penulisan kode.

Pada VB9 untuk menginisialisasi object Collection anda harus menuliskan kode:

   1: Dim objNama As New List(Of String)

   2: objNama.Add("Erick")

   3: objNama.Add("Wely")

   4: objNama.Add("Lutfie")

   5: objNama.Add("Ridi")

6:

   7: For Each nama In objNama

   8:     Console.WriteLine(nama)

   9: Next

Pada VB10 dengan menggunakan Collection Initializer anda dapat menggunakan keyword ‘from’ untuk mempersingkat penulisan kode diatas.

   1: Dim objNama As New List(Of String) From {"erick", "wely", "lutfie", "ridi"}

   2: For Each nama In objNama

   3:     Console.WriteLine(nama)

   4: Next

Anda juga dapat menggunakannya untuk object Dictionary

   1: Dim dictMahasiswa As New Dictionary(Of String, String) From {

   2:                                            {"23080008", "erick"},

   3:                                            {"23080009", "budi"},

   4:                                            {"23080010", "anton"}}

   5: For Each mhs In dictMahasiswa

   6:    Console.WriteLine("Nim :" & mhs.Key & "Nama :" & mhs.Value)

   7: Next

Jika anda ingin menginisialisasi list of class maka anda dapat menggunakan extension method untuk mengoverride method ‘add’ yang ada pada object collection.

   1: Imports System.Runtime.CompilerServices

   2: Module Module1

   3:     'menggunakan extension method

   4:     <Extension()>

   5:     Sub Add(ByVal lstMhs As List(Of Mahasiswa),

   6:             ByVal nim As String,

   7:             ByVal nama As String,

   8:             ByVal ipk As Double)

   9:         lstMhs.Add(New Mahasiswa With {.Nim = nim, .Nama = nama, .IPK = ipk})

  10:     End Sub

11:

  12:     Sub Main()

  13:         Dim list As New List(Of Mahasiswa) From {

  14:             {"23080008", "Erick Kurniawan", 3.4},

  15:             {"22080009", "Budi Anduk", 3.3}

  16:             }

17:

  18:         For Each mhs In list

  19:             Console.WriteLine("Nim :" & mhs.Nim & " Nama :" & mhs.Nama & " Ipk :" & mhs.IPK)

  20:         Next

  21:     End Sub

22:

  23: End Module

Array Literals

ArrayLiteral memberi kemudahan kepada kita untuk memberi nilai ke object array secara langsung, compiler akan secara otomatis meng-infers tipe datanya.

   1: Dim arr1 = {1, 2, 4, 5, 6} 'infers ke tipe integer

   2: Dim arr2 = {1, 2.5, 3.5, 5} 'infers ke tipe double

   3: Dim arr3 = {"erick", "budi"} 'infers ke tipe string

   4: Dim arr4 = {1, "erick"} 'infers ke tipe object (dengan catatan Option Strict On)

5:

   6: 'untuk array multidimensi

   7: Dim matrix1 = {{1, 32, 12}, {23, 45, 67}} 'infers ke tipe int(,)

Fitur VB10 (Implicit Line Continuation)

Erick Kurniawan — Wed, 06 May 2009 17:49:00 GMT

Blog sebelumnya seputar VB10 dapat anda baca di:

Fitur VB10 (Multiline Lambdas)

Pada bahasa VB kita biasanya menggunakan underscore untuk memisahkan satu baris logic code menjadi dua baris code atau lebih. Underscore mengindikasikan bahwa code yang dipisahkan menjadi beberapa baris tersebut sebenarnya masih satu logic code. Pada VB10 compiler VB akan menambahkan underscore secara implicit jadi anda tidak perlu menuliskannya. Namun pada beberapa kasus tertentu anda masih perlu menggunakan underscore. Dengan menggunakan implicit line continuation maka developer tidak perlu lagi menuliskan underscore pada sebagain besar baris code yang ditulis (ini sangat membantu terutama ketika anda menggunakan LINQ).

Compiler VB akan secara implicit menggunakan line continuation pada kodisi-kondisi berikut:

Setelah Attribute
Setelah karakter koma (,)
Setelah karakter dot (.)
Setelah binary operator
Setelah LINQ Query Clause
Setelah karakter (, {, or <%=
Sebelum karakter ), }, or %>

Daftar karakter yang mendukung implicit line continuation dapat anda lihat pada table berikut:

Contoh penggunaan implicit line continuation pada VB10:

Hmm sudah gak sabar nich menggunakan fitur keren ini :)

Fitur VB10 (Multiline Lambdas)

Erick Kurniawan — Wed, 06 May 2009 17:48:00 GMT

Pada blog series kali ini saya ingin mengeksplorasi fitur-fitur baru dari VB10 (VB10 akan dirilis bersama dengan VS2010 dan .NET 4.0). Fitur yang akan kita bahas kali ini adalah Multiline Lambdas, sebenarnya fitur ini sudah disupport di C# 3.0, tapi VB baru menambahkan fitur ini pada VB10.

Pada VB10 anda dapat menggunakan Multiline Lambdas sebagai berikut:

   1: Dim bil() As Integer = {1, 2, 3, 4, 5, 6, 7}

   2: bil = Array.FindAll(bil, Function(n)

   3:                              Console.WriteLine("Array ke-" & n)

   4:                              If n Mod 2 = 0 Then

   5:                                  Return n

   6:                              End If

   7:                          End Function)

   8: For Each num In bil

   9:         Console.WriteLine(num)

  10: Next

outputnya :

Sama seperti Lambda Expression pada VB9 maka parameter dari Lambda tersebut akan diinfer secara otomatis oleh compiler (pada contoh diatas n akan diinfer menjadi tipe integer).

Dengan menggunakan Multiline Lambda anda dapat membuat anonymous delegate dengan mudah contohnya:

   1: Dim cthDelegate = Function(n As Integer)

   2:                               Dim count = 0

   3:                               For i = 1 To n

   4:                                   If n Mod i = 0 Then

   5:                                       count += 1

   6:                                   End If

   7:                               Next

   8:                               If count = 2 Then

   9:                                   Return "Bilangan Prima"

  10:                               Else

  11:                                   Return "Bukan Bilangan Prima"

  12:                               End If

  13:                           End Function

14:

  15: Console.WriteLine(cthDelegate(17))

outputnya :

Jika anda cermati dari kode diatas maka nilai kembalian dari function tersebut adalah tipe “String” (compiler juga secara otomatis akan meng-infer tipenya). Anda juga dapat secara eksplisit menentukan tipe kembalian dari function diatas sehingga compiler tidak akan meng-infer tipenya secara otomatis.

   1: Dim cthDelegate = Function(n As Integer) as String

   2:                               Dim count = 0

   3:                               For i = 1 To n

   4:                                   If n Mod i = 0 Then

   5:                                       count += 1

   6:                                   End If

   7:                               Next

   8:                               If count = 2 Then

   9:                                   Return "Bilangan Prima"

  10:                               Else

  11:                                   Return "Bukan Bilangan Prima"

  12:                               End If

  13:                           End Function

Sub Lambdas

Selain menggunakan “Function” keyword untuk membuat multiline lambda yang mengembalikan nilai, anda juga dapat menggunakan multiline lambda yang tidak mengembalikan nilai menggunakan “sub” keyword .

   1: Dim arrNama() As String = {"erick", "ricky", "joni"}

   2: Array.ForEach(arrNama, Sub(n As String)

   3:                            Dim balik = ""

   4:                            For i = n.Length - 1 To 0 Step -1

   5:                                balik &= n(i)

   6:                            Next

   7:                            Console.WriteLine(balik)

   8:                       End Sub)

outputnya:

Single line Sub Lambdas

Pada VB9 anda hanya dapat menggunakan single expression lambda jika ada return valuenya, misal:

   1: Dim bil() As Integer = {1, 3, 4, 5, 8, 10}

   2: Dim query = bil.Where(Function(n) n Mod 2 = 0)

   3: For Each num In query

   4:     Console.WriteLine(num)

   5: Next

Akan error jika anda tuliskan kode berikut pada VB9:

   1: Dim bil() As Integer = {1, 3, 4, 5, 8, 10}

   2: Array.ForEach(bil, Sub(n) Console.WriteLine(n))

Pada VB10, anda dapat menggunakan keyword “sub” untuk membuat single expression yang tidak mengembalikan nilai

   1: Dim bil() As Integer = {1, 3, 4, 5, 8, 10}

   2: Array.ForEach(bil, Sub(n) Console.WriteLine(If(n Mod 2 = 0, "Genap :" & n, "Ganjil :" & n)))

Event Kuliah Umum bersama MUGI di Universitas Islam Indonesia Jogjakarta

Erick Kurniawan — Fri, 24 Apr 2009 15:05:09 GMT

Pada tanggal 21 april 2009 kemaren MUGI Jogja bekerja sama dengan MIC UGM (thnx to Pak Ridi n Baskoro) telah menyelenggarakan "Kuliah Umum bersama MUGI Jogja" yang dilangsungkan di auditorium Fakultas Teknik Universitas Islam Indonesia (UII) Jogjakarta, adapun materi yang kami bawakan adalah:

Windows 7 Demo oleh Baskoro (MIC UGM)
Internet Explorer 8 in Windows 7 Demo oleh Erick Kurniawan (MUGI Jogja)
7 Development tips for Nowadays Software Ridi Ferdiana (MIC UGM)

Acara Kuliah Umum kemaren berlangsung dari pukul 9.00 sd 13.00 dengan dihadiri oleh 100 peserta yang kebanyakan terdiri dari mahasiswa UII. Acara ini bersifat "free" tanpa dipungut biaya. Peserta sangat antusias dalam mengikuti acara tersebut, ini terlihat dari banyaknya penanya (mpe abis doorprize :) ) thnx to MS Indo yang sudah memberikan CD IE8 untuk dibagikan secara cuma-cuma ke peserta :)

Thnx to mas Samsul dari UII selaku ketua Panitia yang sudah berjuang demi terlaksananya acara ini, semoga semakin banyak mahasiswa UII yang join ke MUGI ^_^

foto-foto yang lain akan menyusul, soalnya kemaren kita lupa bawa kamera, jadi masih menunggu dari panitia ^_^

untuk materi anda dapat download disini download file

warm regards,

Erick Kurniawan

HOL ASP.NET MVC

Erick Kurniawan — Sun, 19 Apr 2009 13:23:00 GMT

Hari sabtu kemaren saya diminta oleh Pak Ridi (MIC UGM) untuk berpartisipasi mengisi workshop di Universitas Atmajaya Jogjakarta, topiknya adalah "ASP.NET MVC", workshop singkat ini berlangsung selama 2.5jam (sesi 1) dan di teruskan sesi 2 tentang "Enterprise Library" oleh Pak Ridi.

Jika anda berminat anda dapat mendownload HOL dan source code dari workshop singkat yang saya bawakan kemaren pada link dibawah ini:

HOL ASP.NET MVC

Source Code

Semoga bisa bermanfaat untuk teman-teman yang ingin mencoba menggunakan aplikasi ASP.NET MVC :)

Fitur VB9 (LINQ to XML dan XML Literal)

Erick Kurniawan — Tue, 14 Apr 2009 17:15:00 GMT

Halo ini adalah posting kesebelas saya tentang fitur dari VB9 tentang XML Literal. Ini adalah fitur dari VB9 yang "cool", pada VB9 XML menjadi "first class citizen" yang berarti anda dapat menuliskan XML secara Literal.

anda dapat melihat posting saya sebelumnya:

Pada jaman dahulu kala (VB8) untuk membuat file XML anda harus menggunakan System.Xml untuk DOM manipulation, contoh kodenya:

   1: Imports System.IO

   2: Imports System.Xml

   3: Module Module1

   4:     Sub Main()

   5:         Using fs As New FileStream("produksample.xml", FileMode.Create)

   6:             Using wt As XmlWriter = XmlWriter.Create(fs)

   7:                 wt.WriteStartDocument()

   8:                 wt.WriteStartElement("Products")

   9:                 wt.WriteStartElement("Product")

  10:                 wt.WriteAttributeString("Id", "KB001")

  11:                 wt.WriteElementString("Name", "Laptop Acer")

  12:                 wt.WriteElementString("Price", "7000000")

  13:                 wt.WriteEndElement()

  14:                 wt.Flush()

  15:             End Using

  16:         End Using

  17:     End Sub

  18: End Module

kode diatas akan menghasilkan file "produksample.xml" sebagai berikut:

   1: <?xml version="1.0" encoding="utf-8"?>

   2: <Products>

   3:     <Product Id="KB001">

   4:     <Name>Laptop Acer</Name>

   5:     <Price>7000000</Price>

   6:     </Product>

   7: </Products>

LINQ to XML

Pada VB9 (.NET 3.5) anda dapat menuliskannya dengan cara yang baru. VB9 mendukung XElement class yang terdapat pada namespace System.Xml.Linq, dengan menggunakan cara penulisan ini code untuk pembuatan dokumen XML tampak menjadi lebih "clean". Class yang ada pada System.Xml.Linq adalah

Class	Deskripsi
XAttribute	Merepresentasikan attribut yang dibuat
XDocument	Merepresentasikan Complete XML Tree
XElement	Merepresentasikan XML Element, dan sebagai dasar untuk mengkonstruksi XML Tree
XName	Merepresentasikan attribut dan element names
XNode	Merepresentasikan base class dari XML Node

Untuk membuat dokumen xml seperti contoh sebelumnya dengan menggunakan XElement anda dapat menuliskan kode berikut:

   1: Imports System.Xml.Linq

   2: Module ContohXElement

   3:     Sub Main()

   4:         Dim xmlProd = New XElement("Products", _

   5:                           New XElement("Product", _

   6:                               New XAttribute("Id", "KB001"), _

   7:                               New XElement("Name", "Laptop Acer"), _

   8:                               New XElement("Price", "7000000")))

   9:         xmlProd.Save("xelementProd.xml")

  10:     End Sub

  11: End Module

XML Literal

VB9 juga menawarkan cara yang lebih simple dan clean selain menggunakan XElement yaitu XML Literal, saat ini XML Literal hanya disupport oleh VB9, C# 3.0 belum menssuport fitur ini (C# 4.0? Maybe ^_^). dengan XML Literal anda dapat menuliskan kode berikut:

   1: Imports System.Xml.Linq

   2: Module ContohXElement

   3:     Sub Main()

   4:         Dim xmlProd = <Products>

   5:                           <Product Id="KB001">

   6:                               <Name>Laptop Acer</Name>

   7:                               <Price>7000000</Price>

   8:                           </Product>

   9:                       </Products>

  10:         xmlProd.Save("literalprod.xml")

  11:     End Sub

  12: End Module

Anda juga dapat mengambil nilai dari attribute atau elemen dalam dokumen tersebut dengan iterasi

   1: Dim xmlProd = <Products>

   2:                   <Product Id="KB001">

   3:                       <Name>Laptop Acer</Name>

   4:                       <Price>7000000</Price>

   5:                   </Product>

   6:                   <Product Id="KB002">

   7:                       <Name>Laptop Toshiba</Name>

   8:                       <Price>9000000</Price>

   9:                   </Product>

  10:               </Products>

  11: For Each produk In xmlProd.<Product>

  12:     Console.WriteLine("Id {0}, Nama {1} dan harganya Rp.{2}", _

  13:                       produk.@Id, _

  14:                       produk.<Name>.Value, _

  15:                       produk.<Price>.Value)

  16: Next

Hasilnya:

Mudah ya? ^_^ jika kita perhatikan ketika anda melakukan iterasi dokumen xml diatas, VS 2008 sudah cukup memberikan intellisense

namun intellisense tersebut tidak dapat menampilkan keterangan nama elemen atau attribut yang ada pada dokumen XML yang anda buat, karena IDE tidak memiliki informasi tentang XML Schema anda, untuk menyelesaikan masalah ini anda dapat mengimports xml shema dari dokumen. Caranya tambahkan XML Schema, cara yang paling mudah adalah dengan menggunakan fitur pada VS 2008.

Tambahkan file xml yang sudah anda buat sebelumnya kedalam project, kemudian buka dengan VS, pilih "Create Schema". Copykan hasil schema yang digenerate kedalam clipboard.

Tambahkan file XML Schema pada project, dan beri nama "ProdShema.xsd".

Kemudian copykan hasil schema yang digenerate pada langkah sebelumnya kedalam file "ProdShema.xsd", jangan lupa untuk mengisi atribut "targetNamespace"

Setelah itu kembali ke kode, dan anda dapat mengimports schema yang sudah anda buat.

Dengan begitu ketika anda mengetikan kode maka bantuan intellisense akan lebih jelas karena dapat mengenali schema dari dokumen anda

wow programming xml dokumen jadi asik klo ada intellisense gini ^_^

Embedded Expression

Anda juga dapat menambahkan embedded expression dalam XML Literal, jika anda pernah menggunakan ASP.NET pasti familiar dengan cara penulisan embedded expression menggunakan keyword <%= %>. Contoh penggunaannya.

   1: Imports System.Xml.Linq

   2: Module EmbeddedExpression

   3:     Sub Main()

   4:         Dim mahasiswa() = {New With {.Nim = "23082321", .Nama = "Erick", .Ipk = 3.5}, _

   5:                      New With {.Nim = "23082322", .Nama = "Bejo", .Ipk = 3.2}, _

   6:                      New With {.Nim = "23082323", .Nama = "Anton", .Ipk = 3.3}}

   7:         Dim xmlStudent = <Students>

   8:                              <%= From mhs In mahasiswa _

   9:                                  Select _

  10:                                  <Student Nim=<%= mhs.Nim %>>

  11:                                      <Nama><%= mhs.Nama %></Nama>

  12:                                      <Ipk><%= mhs.Ipk %></Ipk>

  13:                                  </Student> _

  14:                              %>

  15:                          </Students>

  16:         xmlStudent.Save("students.xml")

  17:         Console.WriteLine(xmlStudent.ToString())

  18:     End Sub

  19: End Module

jika dijalankan programnya akan menampilkan

Pada kode diatas kita menggenerate dokumen xml menggunakan nilai yang diambil dari anonymous types yang sudah kita buat sebelumnya, anda juga dapat menggenerate dokumen XML dengan data yang anda ambil dari database, dll. Embedded Expression juga dapat digunakan untuk menggenerate "VB View" secara dinamis pada ASP.NET MVC.

Selamat mencoba XML Literal dari VB9 ^_^

Fitur VB9 (LINQ Query)

Erick Kurniawan — Wed, 08 Apr 2009 15:51:40 GMT

Halo ini adalah posting kesepuluh saya tentang fitur dari VB9 tentang LINQ Query. LINQ (Language Integrated Query) adalah fitur yang mensupport sintaks query pada general purpose programming language, anda dapat melakukan query ke berbagai sumber data seperti object, Database, XML, dll. Mungkin anda sudah sering melihat kode-kode LINQ di C#, nah kali ini saya akan mencoba mencontohkan versi VB-nya :)

anda dapat melihat posting saya sebelumnya:

LINQ to Object / LINQ to Memory

Misal anda akan mengambil data dari object Array, anda dapat menuliskan kode:

Dim nilai() = {12, 34, 56, 11, 45, 66}
Dim query = From n In nilai _
            Where n Mod 2 = 0 _
            Select n
For Each bil In query
    Console.WriteLine(bil)
Next

query diatas akan mengembalikan bilangan yang genap, anda dapat menuliskannya dalam bentuk Lambda sebagai berikut:

Dim query = nilai.Where(Function(x) x Mod 2 = 0).Select(Function(x) x)
For Each bil In query
    Console.WriteLine(bil)
Next

Object yang dapat diquery dengan LINQ harus bertipe IEnumerable(Of T), Select() dan Where() adalah Extension Method yang ditambahkan ke IEnumerable(Of T), asal dari Select() dan Where() sebenarnya dari System.Linq.Enumerable, aslinya anda dapat menuliskan:

Dim query = Enumerable.Select(Enumerable.Where(nilai, Function(x) x Mod 2 = 0), Function(x) x)
For Each bil In query
    Console.WriteLine(bil)
Next

LINQ to SQL

Selain query ke object, anda dapat juga melakukan query ke database SQL Server, menggunakan OR Mapping tools yang bernama LINQ to SQL. ORM digunakan untuk mapping dari database relational ke object. Misal anda mempunyai database dengan nama MhsDb, kemudian dalam database tersebut terdapat satu table dengan nama Mahasiswa dan fields berikut (nim char(8) primary key, nama varchar(50), dan ipk float).

Pertama buat class dengan nama Mahasiswa.vb, kemudian mapping table Mahasiswa kedalam class:

Imports System.Data.Linq.Mapping
<Table(Name:="dbo.Mahasiswa")> _
Public Class Mahasiswa
    Private _nim As String
    <Column(IsPrimaryKey:=True)> _
    Public Property Nim() As String
        Get
            Return _nim
        End Get
        Set(ByVal value As String)
            _nim = value
        End Set
    End Property

    Private _nama As String
    <Column()> _
    Public Property Nama() As String
        Get
            Return _nama
        End Get
        Set(ByVal value As String)
            _nama = value
        End Set
    End Property

    Private _ipk As Single
    <Column()> _
    Public Property Ipk() As Double
        Get
            Return _ipk
        End Get
        Set(ByVal value As Double)
            _ipk = value
        End Set
    End Property
End Class

Anda dapat juga melakukan mapping secara otomatis menggunakan fasilitas "LINQ to SQL Class" atau "SQL Metal".

Untuk mengakses data menggunakan LINQ to SQL kita harus membuat object DataContext terlebih dahulu, kemudian ambil table yang akan kita query

Imports System.Data
Imports System.Linq
Imports System.Data.Linq

Sub Main()

        Dim strConn = "Data Source=.\SQLEXPRESS;Integrated Security=SSPI;Initial Catalog=MhsDb;"
        Dim db As New DataContext(strConn)
        Dim tMahasiswa = db.GetTable(Of Mahasiswa)()

        Dim query = From m In tMahasiswa _
                    Select m

        For Each mhs In query
            Console.WriteLine(mhs.Nim & " " & mhs.Nama & " " & mhs.Ipk)
        Next
End Sub

LINQ Query Operator

Beberapa operator LINQ yang dapat digunakan adalah:

From : source dari query yang akan digunakan

From <tampung> [As<type>] In <source>

tampung berisi variable tampung yang akan digunakan dalam query
type berisi tipe data dari tampung (tapi tidak harus disebutkan karena vb akan secara otomatis menggunakan local type inference untuk menentukan tipenya). biasanya dapat berupa IEnumerable(Of T) atau IQueryable(Of T)
source berisi referensi ke object source, dapat berupa in-memory collection atau IQueryable(Of T) object

Select : mendefinisikan projection clause dalam query

Select <projection>

projection dapat berisi expression yang mengembalikan satu object, dapat juga berupa tampung dari From clause, atau object yang lebih kompleks.

[alias = ] <column>

anda juga dapat mendefinisikan alias (sifatnya optional), mengindikasikan nama dari property yang akan digenerate oleh anonymous type yang mewakili projection.
column mengacu ke fields atau property pada tampung, tapi dapat juga berupa expression yang lebih kompleks

Contoh:

'mencetak 9 8 7 6 5 4
Dim bil = From i In New Integer() {9, 8, 7, 6, 5, 4} Select i
For Each i In bil
    Console.WriteLine(i)
Next

'menghasilkan anonymous type {Dobel=2,Tripel=3},{Dobel=4,Tripel=6}
Dim bil2 = From i In New Integer() {1, 2} Select Dobel = 2 * i, Tripel = 3 * i
For Each i In bil2
    Console.WriteLine(i.Dobel & " " & i.Tripel)
Next

Order By : digunakan untuk mengurutkan hasil query

Order By <ordering> [Ascending] [Descending]

ordering berisi expression key yang digunakan untuk proses pengurutan

Contoh:

Dim mhs() = {New With {.Nim = "22081234", .IPK = 3.2}, _
             New With {.Nim = "23081235", .IPK = 3.5}, _
             New With {.Nim = "23081231", .IPK = 2.5}}
Dim query = From m In mhs Order By m.Nim Acending Order By m.IPK Select m.Nim, m.IPK
For Each m In query
    Console.WriteLine(m.Nim & " " & m.IPK)
Next

Distinct : melakukan filter terhadap nilai yang terduplikasi dari query

Contoh:

'menghasilkan 1 2 3 4
Dim bil = From i In New Integer() {1, 1, 1, 2, 3, 4} Select i Distinct
For Each b In bil
   Console.Write(b & " ")
Next

Skip dan Take: untuk memfilter range dari nilai hasil query

Take<number> : poisisi
Skip <number> : banyak nilai yang diambil

Contoh:

'menghasilkan 5,6 (ambil dari posisi ke 4 sebanyak 2 nilai)
Dim bil = From i In New Integer() {1, 2, 3, 4, 5, 6, 7, 8, 9, 10} _
          Select i Skip (4) Take (2)
For Each b In bil
    Console.Write(b & " ")
Next

Aggregate : digunakan untuk operasi aggregation, contoh agregation

Count
Sum
Min
Max
Average

Aggregate <tampung> In <source> Into <aggregation list>

Contoh:

'penggunaan Sum
Dim tot = Aggregate i In (From i In New Integer() {1, 2, 3, 4, 5, 6} Select i) Into Total = Sum()
Console.WriteLine(tot)

'penggunaan Count
Dim jml = Aggregate i In (From i In New Integer() {1, 2, 3, 4, 5, 6} Select i) Into Jumlah = Count()
Console.WriteLine(jml)

'penggunaan Min
Dim min = Aggregate i In (From i In New Integer() {1, 2, 3, 4, 5, 6} Select i) Into Minimal = Min()
Console.WriteLine(min)

'penggunaan Average
Dim rata = Aggregate i In (From i In New Integer() {1, 2, 3, 4, 5, 6} Select i) Into Minimal = Average()
Console.WriteLine(rata)

Grouping : digunakan untuk membuat group berdasarkan group expression yang dibuat

Group By <key> Into Aggregate

Contoh:

Dim mhs() = {New With {.Nim = "22081234", .Jurusan = "TI", .IPK = 3.2}, _
             New With {.Nim = "23081235", .Jurusan = "SI", .IPK = 3.5}, _
             New With {.Nim = "23081231", .Jurusan = "SI", .IPK = 2.5}}
Dim query = From m In mhs Group By m.Jurusan Into Anggota = Group
For Each jur In query
   Console.WriteLine(jur.Jurusan)
   For Each m In jur.Anggota
       Console.WriteLine("- NIM :" & m.Nim & " IPK :" & m.IPK)
   Next
Next

Join : menggabungkan multiple source bersama berdasarkan kondisi join tertentu

Join <tampung> In <source> On <key1> equals <key2> and ....

Dim mhs() = {New With {.Nim = "22081234", .Jurusan = "TI", .IPK = 3.2}, _
             New With {.Nim = "23081235", .Jurusan = "SI", .IPK = 3.5}, _
             New With {.Nim = "23081231", .Jurusan = "SI", .IPK = 2.5}}

Dim kul() = {New With {.Kode = "IM2043", .Nama = "Web Database"}, _
             New With {.Kode = "IM2033", .Nama = "Rekayasa Web"}}

Dim ambil() = {New With {.Id = 1, .Kode = "IM2043", .Nim = "22081234"}, _
               New With {.Id = 2, .Kode = "IM2033", .Nim = "23081235"}, _
               New With {.Id = 3, .Kode = "IM2043", .Nim = "23081231"}}
   
Dim query = From m In mhs _
           Join a In ambil On m.Nim Equals a.Nim _
           Join k In kul On a.Kode Equals k.Kode _
           Select m.Nim, k.Nama

For Each hsl In query
       Console.WriteLine("Mahasiswa dengan Nim : " & hsl.Nim & " mengambil Matakuliah : " & hsl.Nama)
Next

demikian beberapa contoh penggunaan LINQ Query di VB9, untuk contoh-contoh lebih detail tentang penggunaan LINQ (VB) akan dibahas di posting2 selanjutnya, viva VB :)

Fitur VB9 (Lambda Expression)

Erick Kurniawan — Wed, 01 Apr 2009 17:25:00 GMT

Halo, setelah lama absen posting tentang VB kangen juga untuk membahas fitur-fitur baru VB :), posting ini adalah posting kesembilan saya tentang fitur dari VB9 yaitu Lambda Expression, Mungkin anda sudah sering menggunakan Lambda Expression di C# 3.0, pada posting kali ini akan ditunjukan juga beberapa perbedaan fitur di VB dan C#.

anda dapat melihat posting saya sebelumnya:

Lambda Expression adalah istilah yang diambil dari functional programming, Lambda Expression digunakan untuk memudahkan anda membuat fungsi/method. contoh penulisan Lambda Expression

Function (e) e + 1

fungsi diatas mempunyai satu parameter e, dan mengembalikan e+1.

Untuk menunjukan penggunaan Lambda Expression pada VB, maka sebagai contoh saya akan membuat array berisi integer dan memfilter yang nilainya > 6 dengan Lambda Expression

Sub Main()
        Dim arrBil() = {4, 5, 7, 9, 12, 3, 2}
        Dim filter = arrBil.Where(Function(b) b > 5)
        For Each i In filter
            Console.WriteLine(i)
        Next
End Sub

Lambda Expression dan Delegates

Lambda Expression dapat digunakan untuk mempermudah penggunaan delegates di VB. Tanpa Lambda anda dapat menuliskan:

'deklarasi delegates
Public Delegate Function UbahInt(ByVal x As Integer) As Integer

'buat fungsi yang akan ditunjuk oleh delegates
Function Gandakan(ByVal x As Integer) As Integer
        Return x * 2
End Function

Kemudian buat instance delegates sebagai berikut

Sub Main()
        Dim mydel As UbahInt = New UbahInt(AddressOf Gandakan)
        Console.WriteLine("{0}", mydel(5))
End Sub

Maka program diatas akan mencetak 10.

Dengan menggunakan Lambda Expression anda dapat menuliskan :

Public Delegate Function UbahInt(ByVal x As Integer) As Integer

Sub Main()
        Dim mydel As UbahInt = Function(x) x * 2
        Console.WriteLine(mydel(5))
End Sub

Program diatas juga akan mencetak 10 sama dengan sebelumnya, tapi dengan menggunakan Lambda Expression penambahan method menjadi lebih mudah :)

Menggunakan Lambda dengan Dua Parameter

Anda juga dapat menggunakan Lambda dengan dua parameter, cara penulisannya:

'delegates dengan dua parameter
Public Delegate Function Kali(ByVal x As Integer, ByVal y As Integer) As Integer

'mencetak 5*6=30
Sub Main()
      Dim mydel = Function(x, y) x * y
      Console.WriteLine(mydel(5, 6))
End Sub

Anda juga dapat menggunakan Select() extension method dengan Lambda Expression yang mempunyai dua parameter, parameter pertama untuk nilai sedangkan parameter kedua untuk index

Dim nama() = {"erick", "wely", "sony", "ridi"}
Dim filter = nama.Select(Function(x, i) "Nama ke " + i.ToString() + " : " + x)
For Each i In filter
     Console.WriteLine(i)
Next

jika program dijalankan akan mencetak:

Statement Lambda Expression

VB9 belum mendukung Statement Lambda Expression seperti yang ada pada C# 3.0, VB akan mensupport fitur ini pada versi VB10. Jika menggunakan Statement Lambda Expression di C# anda dapat menuliskan:

//menggunakan Statement Lamda pada C# 
string[] nama = new[] { "erick","wely","sony","ridi","eriawan" };

foreach (string n in nama.Where(
       x => {
           if (x.Contains("eri"))
                  return true;
           else
                  return false;
            }
         ))

Console.WriteLine(n);

dengan VB9 anda dapat menghasilkan output yang sama dengan menuliskan kode sebagai berikut:

Function CekNama(ByVal nama As String)
        If nama.Contains("eri") Then
            Return True
        Else
            Return False
        End If
End Function

Sub Main()
        Dim nama() = {"erick", "wely", "sony", "eriawan"}
        Dim filter = nama.Where(Function(x) CekNama(x))
        For Each n In filter
            Console.WriteLine(n)
        Next
End Sub

maka akan dicetak output:

happy coding ^_^

LIstView dan Data Pager Control (bagian 2)

Erick Kurniawan — Tue, 24 Mar 2009 13:52:41 GMT

Posting ini adalah lanjutan dari posting sebelumnya di

Topik yang akan dibahas pada posting kali ini:

Sorting dengan ListView
Edit, Delete data dengan ListView
Insert data dengan ListView
Sekilas DataPager Control
Contoh menggunakan DataPager
Custom Paging

Source code untuk contoh-contoh aplikasi dapat anda download di

download source code disini

Sorting Dengan ListView

Anda juga dapat menambahkan sorting pada ListView control dengan cara merubah property ‘CommandName’ menjadi ‘Sort’ dan ‘CommandArgument’ berisi nama kolom untuk yg akan disorting.

Contoh sorting dengan ListView Control (ListSort.aspx)

   1: <form id="form1" runat="server">

   2: <div>

   3:   <asp:SqlDataSource ID="sdsKategori" runat="server"

   4:     ConnectionString="<%$

   5:     ConnectionStrings:MhsConnectionString %>"

   6:     SelectCommand="SELECT * FROM

   7:       Kategori"></asp:SqlDataSource>

   8:    <asp:ListView ID="lvBerita" runat="server"

   9:      DataSourceID="sdsKategori">

  10:      <LayoutTemplate>

  11:       <table border="1px" style="border-collapse:collapse;">

  12:         <thead>

  13:         <tr>

  14:           <th><asp:LinkButton ID="lnkId" Text="ID"

  15:             CommandName="Sort" CommandArgument="id_kat"

  16:             runat="server" /></th>

  17:           <th><asp:LinkButton ID="lnkNama" Text="Nama

  18:             Kategori" CommandName="Sort"

  19:             CommandArgument="nama_kat"

  20:             runat="server" /></th>

  21:         </tr>

  22:         </thead>

  23:         <tbody>

  24:           <asp:PlaceHolder ID="itemPlaceHolder"

  25:             runat="server" />

  26:         </tbody>

  27:       </table>

  28:      </LayoutTemplate>

  29:      <ItemTemplate>

  30:        <tr>

  31:          <td><%# Eval("id_kat") %></td>

  32:          <td><%# Eval("nama_kat") %></td>

  33:        </tr>

  34:      </ItemTemplate>

  35:    </asp:ListView>

  36: </div>

  37: </form>

Edit, Delete, Insert Data dengan ListView

ListView menggunakan tag-tag <EditItemTemplate>, <DeleteItemTemplate>, <InsertItemTemplate> untuk inser, edit, delete data. Didalam tag tersebut anda dapat membuat tampilan ketika tombol edit, insert, atau delete ditekan.

Contoh Edit dan Delete data menggunakan ListView (EditList.aspx)

   1: <form id="form1" runat="server">

   2: <div>

   3:   <asp:SqlDataSource ID="sdsKategori" runat="server"

   4:     ConnectionString="<%$

   5:     ConnectionStrings:MhsConnectionString %>"

   6:     SelectCommand="SELECT * FROM [Kategori]"

   7:     DeleteCommand="DELETE FROM [Kategori]

   8:       WHERE [id_kat] = @id_kat"

   9:     UpdateCommand="UPDATE [Kategori] SET [nama_kat] =

  10:       @nama_kat WHERE [id_kat] = @id_kat">

  11:     <DeleteParameters>

  12:       <asp:Parameter Name="id_kat" Type="Int32" />

  13:     </DeleteParameters>

  14:     <UpdateParameters>

  15:       <asp:Parameter Name="nama_kat" Type="String" />

  16:       <asp:Parameter Name="id_kat" Type="Int32" />

  17:     </UpdateParameters>

  18:   </asp:SqlDataSource>

  19:   <asp:ListView ID="lvKategori" runat="server"

  20:     DataKeyNames="id_kat" DataSourceID="sdsKategori">

  21:     <LayoutTemplate>

  22:      <asp:PlaceHolder ID="itemPlaceholder" runat="server" />

  23:     </LayoutTemplate>

  24:     <ItemTemplate>

  25:       <div style="border:solid 1px black;width:250px">

  26:         <h3><%# Eval("nama_kat") %></h3>

  27:         <p>Id: <%# Eval("id_kat") %></p><hr />

  28:         <asp:LinkButton id="lnkEdit" Text="{Edit}"

  29:           CommandName="Edit" Runat="server" />

  30:         <asp:LinkButton id="lnkDelete" Text="{Delete}"

  31:           CommandName="Delete" Runat="server"

  32:           OnClientClick="return confirm('Anda yakin

  33:           mendelete data?')" />

  34:       </div>

  35:     </ItemTemplate>

  36:     <EditItemTemplate>

  37:       <div style="border:solid 1px black;width:250px">

  38:         Nama Kategori :<asp:TextBox ID="txtKat" Text='<%#

  39:           Bind("nama_kat") %>' runat="server" />

  40:         <asp:RequiredFieldValidator ID="rfvKat"

  41:           runat="server" ControlToValidate="txtKat"

  42:           ErrorMessage="{required}" /><hr />

  43:         <asp:LinkButton id="lnkUpdate" Text="{Update}"

  44:           CommandName="Update" Runat="server" />

  45:         <asp:LinkButton id="lnkCancel" Text="{Cancel}"

  46:           CommandName="Cancel" Runat="server" />

  47:       </div>

  48:       </EditItemTemplate>

  49:   </asp:ListView>

  50: </div>

  51: </form>

Contoh insert data menggunakan ListView (InsertList.aspx)

   1: <form id="form1" runat="server">

   2: <div>

   3:   <asp:SqlDataSource ID="sdsKategori" runat="server"

   4:     ConnectionString="<%$

   5:     ConnectionStrings:MhsConnectionString %>"

   6:     InsertCommand="INSERT INTO [Kategori] ([nama_kat])

   7:       VALUES (@nama_kat)"

   8:     SelectCommand="SELECT * FROM [Kategori]">

   9:     <InsertParameters>

  10:       <asp:Parameter Name="nama_kat" Type="String" />

  11:     </InsertParameters>

  12:   </asp:SqlDataSource>

  13:   <asp:ListView ID="lvKategori" runat="server"

  14:     DataSourceID="sdsKategori"

  15:     InsertItemPosition="FirstItem">

  16:   <LayoutTemplate>

  17:     <asp:PlaceHolder ID="itemPlaceHolder" runat="server" />

  18:   </LayoutTemplate>

  19:   <ItemTemplate>

  20:    <div style="border:solid 1px black;width:250px">

  21:     <h3><%# Eval("nama_kat") %></h3>

  22:     <p>Id Kategori : <%# Eval("id_kat") %></p><hr />

  23:    </div>

  24:   </ItemTemplate>

  25:   <InsertItemTemplate>

  26:    <div style="border:solid 1px black;width:250px">

  27:      <h3>Tambah Kategori</h3>

  28:      Nama Kategori :<asp:TextBox ID="txtKat" Text='<%#

  29:        Bind("nama_kat") %>' runat="server" /><hr />

  30:      <asp:LinkButton ID="lnkInsert" Text="{Insert}"

  31:        CommandName="Insert" runat="server" />

  32:    </div>

  33:   </InsertItemTemplate>

  34:   </asp:ListView>

  35: </div>

  36: </form>

DataPager Control

DataPager adalah pasangan dari ListView yang digunakan untuk paging halaman. DataPager dapat digunakan oleh semua control yang mengimplementasikan interface IPageableItemContainer. Di ASP.NET 3.5 baru ada satu control yang mengimplementasikan interface tersebut yaitu ListView ^_^

DataPager control mempunyai beberapa property yang penting yaitu:

PageSize: jumlah data yang akan ditampilkan.
PagedControlId: ambil atau set control pada halaman.
Fields: ambil fields yang ada pada DataPager.
StartRowIndex: ambil index dari item pertama yang ditampilkan.
MaximumRows: ambil maksimum row yang diambil dari data source.
TotalRowCount: ambil total number dari items yang ada pada data source.
NextPreviousPagerFields : untuk menampilkan link dalam bentuk next, previous, first dan last.
NumericPagerFileds: menampilkan link dalam bentuk numeric.
TemplatePagerField: membuat custom user interface pada paging.

Contoh menggunakan DataPager (ShowDataPager.aspx)

   1: <form id="form1" runat="server">

   2: <div>

   3:   <asp:SqlDataSource ID="sdsBerita" runat="server"

   4:     ConnectionString="<%$

   5:     ConnectionStrings:MhsConnectionString %>"

   6:     SelectCommand="SELECT * FROM

   7:       [Berita]"></asp:SqlDataSource>

   8:     <asp:ListView ID="lvBerita" runat="server"

   9:       DataSourceID="sdsBerita">

  10:     <LayoutTemplate>

  11:     <table border="2">

  12:     <thead>

  13:       <th>Judul</th><th>Berita</th><th>Tanggal</th>

  14:     </thead>

  15:     <asp:PlaceHolder ID="itemPlaceHolder" runat="server" />

  16:     </table>

  17:     <asp:DataPager ID="dpBerita" PageSize="2"

  18:       runat="server">

  19:       <Fields>

  20:         <asp:NextPreviousPagerField

  21:           ShowFirstPageButton="true"

  22:           ShowPreviousPageButton="true"

  23:           ShowNextPageButton="false"

  24:           ShowLastPageButton="false" />

  25:         <asp:NumericPagerField />

  26:         <asp:NextPreviousPagerField

  27:           ShowFirstPageButton="false"

  28:           ShowPreviousPageButton="false"

  29:           ShowNextPageButton="true"

  30:           ShowLastPageButton="true" />

  31:       </Fields>

  32:     </asp:DataPager>

  33:     </LayoutTemplate>

  34:     <ItemTemplate>

  35:       <tr>

  36:         <td><%# Eval("judul_berita") %></td>

  37:         <td><%# Eval("detail_berita") %></td>

  38:         <td><%# Eval("tanggal") %></td>

  39:       </tr>

  40:     </ItemTemplate>

  41:   </asp:ListView>

  42: </div>

  43: </form>

Membuat Custom Paging

Jika anda tidak puas dengan default paging yang disediakan, anda dapat menggunakan TemplatePagerField.

Contoh menggunakan DataPager TemplatePagerField (PagerTemplate.aspx)

   1: <form id="form1" runat="server">

   2: <div>

   3:   <asp:SqlDataSource ID="sdsBerita" runat="server"

   4:     ConnectionString="<%$

   5:     ConnectionStrings:MhsConnectionString %>"

   6:     SelectCommand="SELECT * FROM

   7:       [Berita]"></asp:SqlDataSource>

   8:    <asp:ListView ID="lvBerita" runat="server"

   9:       DataSourceID="sdsBerita">

  10:     <LayoutTemplate>

  11:      <table border="1">

  12:      <thead>

  13:         <th>Judul</th><th>Berita</th><th>Tanggal</th>

  14:      </thead>

  15:      <asp:PlaceHolder ID="itemPlaceholder" runat="server" />

  16:      </table>

  17:      <asp:DataPager ID="dpBerita" runat="server"

  18:        PageSize="2">

  19:        <Fields>

  20:          <asp:TemplatePagerField

  21:            OnPagerCommand="dpBerita_OnPagerCommand">

  22:          <PagerTemplate>

  23:            <asp:LinkButton ID="lnkPrev" Text="{Prev}"

  24:              CommandName="Previous" runat="server" />

  25:            <asp:LinkButton ID="lnkNext" Text="{Next}"

  26:              CommandName="Next" runat="server" />

  27:          </PagerTemplate>

  28:          </asp:TemplatePagerField>

  29:        </Fields>

  30:      </asp:DataPager>

  31:     </LayoutTemplate>

  32:     <ItemTemplate>

  33:       <tr>

  34:         <td><%# Eval("judul_berita") %></td>

  35:         <td><%# Eval("detail_berita") %></td>

  36:         <td><%# Eval("tanggal") %></td>

  37:       </tr>

  38:     </ItemTemplate>

  39:    </asp:ListView>

  40: </div>

  41: </form>

Kemudian tambahkan kode berikut pada event ‘OnPagerCommand’ pada TemplateFields.

   1: protected void dpBerita_OnPagerCommand(object sender,

   2: DataPagerCommandEventArgs e) {

   3:     e.NewMaximumRows = e.Item.Pager.MaximumRows;

   4:     switch (e.CommandName) {

   5:     case "Previous":

   6:       if (e.Item.Pager.StartRowIndex > 0)

   7:         e.NewStartRowIndex = e.Item.Pager.StartRowIndex - 2;

   8:       break;

   9:     case "Next":

  10:         e.NewStartRowIndex = e.Item.Pager.StartRowIndex + 2;

  11:       break;

  12:     }

  13: }

Dibandingkan dengan GridView, Kombinasi ListView dan DataPager menawarkan fleksibilitas yang lebih besar kepada programmer untuk memodifikasi tampilan dan program. Secara pribadi saya menyarankan penggunaan dua control baru ini daripada control lama seperti GridView, DataList, atau Repeater.

selesai ^_^